Bien qu’il y ai déja un article sur l’Ethernet avec l’arduino grâce au ENC28j60, j’ai reçu cette semaine un shield pour Ethernet pour arduino Uno/Mega basé sur la puce w5100.

Il sagit d’un shield comme ceux proposé par Arduino sauce chinoise biensur.

On va juste utiliser un des exemples pour le tester: L’exemple, WebServer.

Branchements

Il n’y a vraiment rien à faire, si ce n’est enficher votre shield Ethernet dans l’arduino (UNO).

branchement_ethernet

Code

La Mac et l’adresse IP

Ouvrez l’IDE Arduino et ouvrez l’exemple suivant: Fichier -> Exemples -> Ethernet -> WebServer

Le code consiste à balayer l’un après l’autre via une boucle for les six entrées analogiques A0 à A5

Quelques lignes importantes de ce code:

byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 1, 177);

 

La première ligne est la « MAC » assignée à votre shield, la seconde ligne est quand à elle l’adresse ip qui lui sera attribuée
Par défaut, je n’ai pas touché à la mac cependant dans mon code propre j’ai remplacé l’adresse ip en: IPAddress ip(192, 168, 0, 20);

Le port server

EthernetServer server(80);

Comme précisé dans les commentaires du code le port par défaut pour le HTTP est le port 80. Ce qui vous permettrai d’acceder à votre page en tapant uniquement l’adresse IP dans le navigateur.

ethernet_port80

 

Si vous veniez à modifier le port server, il faudrai alors le préciser dans votre navigateur. Si j’utilise par exemple le port 800 donc:

EthernetServer server(800);

Je devrai passer par l’adresse: 192.168.0.20:800

ethernet_port800

Pour la suite, a vous de brancher différents capteurs sur les entrées analogiques pour récupérer leurs valeurs.

Ajouter du contenu

Je n’ai pas encore étudié la librairie Ethernet de l’Arduino. Cependant vu la simplicité du code, on pourrai simplement ajouter un titre a la page (Juste avant les valeurs obtenues).

On constate que pour écrire de l’HTML dans la page, la fonction client.print / client.println est utilisée.

          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");

Bien juste en dessous de la derniere ligne (client.println(«  »); on va ajouter notre titre:

          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          client.println("<h1>Lecture des ports analogiques</h1><br>");

le H1 correspondant au balisage d’un titre et le br à un saut de ligne.

titre_ethernet_shield (1)

 

Je vais m’arrêter ici pour le test de ce shield et laisser mon avis.

Malgré un encombrement plus important que l’ENC28J60 vu l’utilisation de l’arduino uno et de la taille du shield. C’est surement le module ethernet que je préfère d’une part il est « Plug & Play » On enfiche le shield, on upload le code et c’est parti.
Le teste de ce shield m’aura pris 5 minutes à tout casser.
L’exemple utilisé ici est l’officiel d’Arduino, il est simple d’utilisation et à une bonne documentation (lien ci-dessous.)

Lien vers la documentation et librairie

Le code complet que j’ai utilisé:

  /*
  Web Server

 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield.

 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)

 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe

 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = {
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
IPAddress ip(192, 168, 0, 20);

// Initialize the Ethernet server library
// with the IP address and port you want to use
// (port 80 is default for HTTP):
  EthernetServer server(800);

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          client.println("<h1>Lecture des ports analogiques</h1><br>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        }
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}