Mesurer la température et humidité avec le DHT11 ou DHT22

Besoin de connaitre la température et l’humidité de votre environnement ? Le module DHT11 ou DHT 22 et l’Arduino sont là pour vous.

Ce dont vous aurez besoin

• Un Arduino Uno – Disponible ici
• Des câbles de prototypage rapide – Disponible ici
• Une platine de prototypage rapide – Disponible ici

• Un module DHT11 – Disponible ici

PinOut et connexion du module DHT11

• GND correspond à la masse. A brancher au GND de l’Arduino.
• DATA ou OUT correspond au signal. A connecter a la broche D2 de l’Arduino pour cet Article.
• VCC correspond à l’alimentation du module. A connecter au 5V de l’Arduino.

Installer la librairie DHT11, DHT22 sur le logiciel Arduino

Cliquez sur « croquis » > « Inclure une bibliothèque » > « gérer les bibliothèques« 

Dans la barre de recherche tapez « DHT11 » et installez la bibliothèque « DHT sensor library » par « Adafruit« .

Code Arduino DHT11

Lancez l’exemple présent dans la librairie. Pour cela cliquez sur « fichiers » > « exemples » > » DHT sensor library » > « DHTtester« . Vous devriez avoir ceci:

// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:
// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library
// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 2     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 3 (on the right) of the sensor to GROUND (if your sensor has 3 pins)
// Connect pin 4 (on the right) of the sensor to GROUND and leave the pin 3 EMPTY (if your sensor has 4 pins)
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("°C "));
  Serial.print(f);
  Serial.print(F("°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("°C "));
  Serial.print(hif);
  Serial.println(F("°F"));
}

Sélectionnez le type de module que vous possédez dans le code. Pour çà, décommenté la ligne correspondante à votre DHT en supprimant les deux antislashs //. ce sera le DHT11 dans mon cas.

// Uncomment whatever type you're using!
#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

Téléversez ensuite le code sur votre Arduino et ouvrez votre moniteur série en cliquant sur la petite loupe présente en haut à droite de votre logiciel Arduino

Vous devriez récupérer l’humidité et la température comme ceci